script monitor trafik mikrotik

Yup, dah tau maksudnya kan ? kali ini saya akan share tips gimana caranya jalanin monitor trafik pada interface tertentu (ether1 misalnya) pada pelanggan, yang nantinya dapat digunakan sebagai report ke pelanggan bahwa penggunaan dalam satu bulan ini sudah mencapai sekian GigaByte. Begitu lah kira kira. nah berikut scriptnya, silahkan dibikin scheduler

:global iface ether1
:global trafikawal
:global trafik
# reset tanggal 1
#/system ntp client set primary-ntp=[:resolve id.pool.ntp.org] enabled=yes
#/system clock set time-zone-name="Asia/Jakarta"
:local date [/system clock get date]
:local tanggal [ :pick $date 4 6 ]
#:log warning $tanggal
:if ($tanggal = 1) do={:set trafikawal 0}
:set trafikawal [/interface get [find name=$iface] tx-byte]
   :if ($trafikawal > 1073741824) do={
   :set trafik ($trafikawal / 1073741824)
   :set trafik ($trafik." GB")
   } else={
   :set trafik ($trafikawal / 1048576)
   :set trafik ($trafik." MB")
   }
:log warning "trafik $iface = $trafik"
/in ethernet set $iface comment="$trafikawal"

Nah, setelah diteliti lagi, ternyata script diatas masih ada kekurangan, yaitu ketika perangkat reboot, kereset jadi 0, akhirnya gw ubah jadi revisi scriptnya begini

:global iface ether1
:global trafikFresh
:global trafikSave
:global trafikBit
:global trafikBytes
:global trafikTotal
:local date [/system clock get date]
:local tanggal [ :pick $date 4 6 ]
#:log warning $tanggal
:if ($tanggal = 1) do={:set trafikBit 0}
# jika direboot ambil dari comment interface
:if ([:len $trafikFresh ] = 0) do={
:set trafikSave [/interface get [find name=$iface] comment]
# catat ke variable
:set trafikFresh [/interface get [find name=$iface] tx-byte]
:set trafikTotal ([:tonum $trafikSave] + [:tonum $trafikFresh])
:set trafikBit $trafikTotal
} else={
:set trafikBit  [/interface get [find name=$iface] tx-byte]
:set trafikTotal ([:tonum $trafikSave] + [:tonum $trafikBit])
}
# jika ukuran gigabyte
:if ($trafikTotal > 1073741824) do={
:set trafikBytes ($trafikTotal / 1073741824)
:set trafikBytes ($trafikBytes." GB")
} else={
:set trafikBytes ($trafikTotal / 1048576)
:set trafikBytes ($trafikBytes." MB")
}
:log warning "trafik $iface = $trafikBytes"
/in ethernet set $iface comment="$trafikTotal"

nanti hasilnya seperti berikut :

Continue

preview inix

Continue

Script Mikrotik Cek Intermittent

Hmm.. kali ini mimin bakal share tips & trik cara gimana saat link intermittent maka dilakukan tindakan, di sini mimin disable peer yg ngarah ke sono. Bisa sobat kembangkan sendiri yah. Ok langsung aja bikin scheduler

:global intermit
:global melar
:global limitnotif
:local avgRtt;
:local pin
:local pout
:local target 124.195.38.1
/tool flood-ping $target count=10 do={
  :if ($sent = 10) do={
    :set avgRtt $"avg-rtt"
    :set pout $sent
    :set pin $received
  }
}
:local ploss (100 - (($pin * 100) / $pout))
:local LogErrorMsg ("Ping average for host%0A$target = ".[:tostr $avgRtt]."ms%0Apacket loss = ".[:tostr $ploss]."%")
:local LogWarnMsg ("Ping average for host%0A$target = ".[:tostr $avgRtt]."ms%0Apacket loss = ".[:tostr $ploss]."%")
:local LogError ("Ping average for $target = ".[:tostr $avgRtt]."ms - packet loss: ".[:tostr $ploss]."%")
:local LogWarn ("Ping average for $target = ".[:tostr $avgRtt]."ms - packet loss: ".[:tostr $ploss]."%")
:if ($avgRtt > 20) do={
:set melar ($melar +1)
:log error "$LogError"
} else={
:log warning "$LogWarn"
:set melar 0
}
# jika packetloss diatas 10% maka
:if ([:tostr $ploss] > 10) do={
   :set intermit ($intermit +1)
   :set limitnotif ($limitnotif +1)
   } else={
   :set intermit 0
   }
# jika intermitent terus
:if ($intermit >=10) do={
   :local pesan "$LogErrorMsg"
   /routing bgp peer set [find name~"INIX" disabled=no] disabled=yes
   /ip firewall mangle set [find comment="backup_conn" disabled=yes] disabled=no
   :if ($limitnotif = 2) do={
      /tool fetch url="https://api.telegram.org/bot380921546:AAGn69QpFDuLSOQd3E3JtI5nhfKDkdKMW/sendMessage?chat_id=-20353xxx&text=$pesan" keep-result=no
     }
   }
# jika tidak intermitent
:if ($intermit = 0) do={
   :if ($limitnotif >=10)  do={
   :set limitnotif 0
   }
   :if ($limitnotif =0) do={
   :set limitnotif ($limitnotif +1)
   }
   /routing bgp peer set [find name~"INIX" disabled=yes] disabled=no
   /ip firewall mangle set [find comment="backup_conn" disabled=no] disabled=yes
   :local pesan "$LogWarnMsg"
   :if ($limitnotif =2) do={
      /tool fetch url="https://api.telegram.org/bot380921546:AAGn69QpFDuLSOQd3E3JtI5nhfKDkdKMW/sendMessage?chat_id=-20353xxx&text=$pesan" keep-result=no
      }
   }

Continue

Redial L2TP Mikrotik Automatic

Pernah nggak kalian membuat VPN server, entah itu PPTP, EOIP, L2TP, dan lain sebagainya ??
Permasalahan yang mimin hadapi ketika membuat VPN server pada MikroTik, ketika koneksi yg ditumpangi (baca:InetBroadband) kadang suka ngetrip, terkadang session L2TP menjadi diskonek yg mengakibatkan laju jalur L2TP terhambat, Solusinya di redial, atau pada ppp active dilakukan remove secara manual.

Hal ini sangat merepotkan kl harus manual, soalnya mimin sering otw ga sempet monitor ngawasin 24jam! Nah solusi berikut ini sangat recomended bagi anda yang bekerja sebagai VPNers (yaelah). Langsung aja deh, buat scheduler di mikrotik kalian isinya begini.

:global count [/ppp active print count-only]
:local i
:for i from=1 to=$count do={
   :global user
   :global vpnip
   :set user [/ppp active get $i name];
   :delay 1
   :set vpnip [/ppp active get $i address];
   :delay 1
   :if ([/ping $vpnip count=2] = 0) do={
      /ppp active remove numbers=$i
      :log error "$user $vpnip request time out!"
      } else={
      :log warning "$user $vpnip is reply..."
      }
   }
 }

Continue

Monitor Ethernet Mikrotik Telegram

Kali ini saya akan bagi tips buat monitoring Rate pada Ethernet Mikrotik lalu dilaporkan ke Telegram. OK langsung aja ya, buat scheduler isinya seperti berikut

:global perulangan
:global statusEth
:global iface "ether2-CDIX"
/int eth monitor ether2 once do={
   :if ($"rate" = "100Mbps" && $perulangan <3) do={
      :set statusEth 0
      :set perulangan ($perulangan +1)
      :log error "$iface is 100Mbps"
      :local pesan "$iface is 100Mbps";
      /tool fetch url="https://api.telegram.org/bot380921xxx:AAGn69QpFDuLSOQd3E3JtIJxxxxx/sendMessage?chat_id=-20353xxx&text=$pesan" keep-result=no
      :if ($perulangan = 3 && $statusEth = 0) do={
         :log error "$iface MASIH 100Mbps"
         :local pesan "$iface MASIH 100Mbps"
         /tool fetch url="https://api.telegram.org/bot380921xxx:AAGn69QpFDuLSOQd3E3JtIJxxxxx/sendMessage?chat_id=-20353xxx&text=$pesan" keep-result=no
         }
      } else={
         :set statusEth 1
         :if ($statusEth = 1 && $perulangan >= 1000) do={:set perulangan 1}
         :if ($statusEth = 1 && $perulangan >= 1) do={:set perulangan ($perulangan +1)}
         :if ($perulangan = 2) do={
            :log warning "$iface 1Gbps"
            :local pesan "Alhamdulillaah $iface 1Gbps";
            /tool fetch url="https://api.telegram.org/bot380921xxx:AAGn69QpFDuLSOQd3E3JtIJxxxxx/sendMessage?chat_id=-20353xxx&text=$pesan" keep-result=no
            }
      }
}

Continue

Tangkap Lease Android DHCP Mikrotik

sebagai catatan untuk menangkap gadget yang berada di dhcp-server leases mikrotik kemudian ditambahkan ke addresslist. terserah mau di mark routing atau bagaimana yg jelas sudah masuk di addresslist

:local newDynamics value=[/ip dhcp-server lease find dynamic=yes];
:local newList value="";
:foreach i in=[$newDynamics] do={
:local dynamicIP [/ip dhcp-server lease get $i address];
:local dynamicMAC [/ip dhcp-server lease get $i mac-address];
:local dynamicHOST [/ip dhcp-server lease get $i host-name];
:if ($dynamicHOST~"(Andro|andro|Redmi|redmi|Vivo|vivo|Iphone|iphone|Galaxy|galaxy|BLACKBER)") do={
      /ip firewall address-list add list=cidr_hs_office address=$dynamicIP comment=$dynamicHOST
      :log warning "$dynamicIP added"
      }
}

Continue